Blocks of defect zero

Definition\(p\)-soluble groups#✓fully proved

Let \(p\) be a natural number. A group \(G\) is \(p\)-soluble when it has a subnormal series \(1 = H_0 \le H_1 \le \dots \le H_n = G\), each \(H_i\) normal in \(H_{i+1}\), whose factors \(H_{i+1}/H_i\) are \(p\)-groups or have order prime to \(p\). Here an infinite factor is taken to have order \(0\).

def IsPSoluble (p : ℕ) (G : Type*) [Group G] : Prop :=
  ∃ (n : ℕ) (H : Fin (n + 1) → Subgroup G), H 0 = ⊥ ∧ H (Fin.last n) = ⊤ ∧
    ∀ i : Fin n, H i.castSucc ≤ H i.succ ∧
      ∃ _ : ((H i.castSucc).subgroupOf (H i.succ)).Normal,
        IsPGroup p (H i.succ ⧸ (H i.castSucc).subgroupOf (H i.succ)) ∨
          (Nat.card (H i.succ ⧸ (H i.castSucc).subgroupOf (H i.succ))).Coprime p

Used by 1

Used byKourovka Problem 12.26

DefinitionGroups with a \(p\)-block of defect zero#✓fully proved

Let \(p\) be a natural number. A group \(G\) has a \(p\)-block of defect zero when some irreducible finite-dimensional complex representation of \(G\) has degree divisible by \(p^{v_p(|G|)}\), where \(v_p(|G|)\) is the exponent of \(p\) in the prime factorization of the order \(|G|\) of \(G\) (this exponent is \(0\) when \(p\) is not prime or \(G\) is infinite). For a prime \(p\) and a finite group \(G\), the number \(p^{v_p(|G|)}\) is \(|G|_p\), the largest power of \(p\) dividing \(|G|\).

By Brauer's theory the \(p\)-blocks of defect zero are exactly the singletons \(\{\chi\}\) with \(\chi\) irreducible and \(|G|_p \mid \chi(1)\).

def HasDefectZeroBlock (p : ℕ) (G : Type) [Group G] : Prop :=
  ∃ (V : Type) (_ : AddCommGroup V) (_ : Module ℂ V) (_ : FiniteDimensional ℂ V)
    (ρ : Representation ℂ G V), ρ.IsIrreducible ∧
      p ^ (Nat.card G).factorization p ∣ Module.finrank ℂ V

Used by 1

Used byKourovka Problem 12.26

DefinitionKourovka Problem 12.26#✓fully proved

This is the proposition (Shi Shengming) that for every prime \(p\) and every finite \(p\)-soluble group \(G\), the group \(G\) has a \(p\)-block of defect zero if and only if some normal subgroup \(N\) of \(G\) of order prime to \(p\) contains an element \(x\) whose centralizer \(C_G(x)\) in \(G\) has order prime to \(p\).

Equivalently, some \(x \in O_{p'}(G)\) has a centralizer of order prime to \(p\), since \(O_{p'}(G)\) is the largest normal subgroup of \(G\) of order prime to \(p\).

def defectZeroBlockIffPRegularCentralizer : Prop :=
  ∀ p : ℕ, p.Prime → ∀ (G : Type) [Group G] [Finite G], IsPSoluble p G →
    (HasDefectZeroBlock p G ↔
      ∃ N : Subgroup G, N.Normal ∧ (Nat.card N).Coprime p ∧
        ∃ x ∈ N, (Nat.card (Subgroup.centralizer {x})).Coprime p)

Uses 2 · Used by 1

Statement usesGroups with a \(p\)-block of defect zero · \(p\)-soluble groups

Used byRefutation of Kourovka Problem 12.26

TheoremRefutation of Kourovka Problem 12.26#●ready to prove

The proposition of Kourovka Problem 12.26 is false: it is not the case that for every prime \(p\) and every finite \(p\)-soluble group \(G\), the group \(G\) has a \(p\)-block of defect zero if and only if some normal subgroup \(N\) of \(G\) of order prime to \(p\) contains an element \(x\) whose centralizer \(C_G(x)\) in \(G\) has order prime to \(p\).

V. I. Zenkov's counterexample: the group \(G = 3^2.\mathrm{GL}_2(3)\) of order \(432\) is soluble and has a \(2\)-block of defect zero (an irreducible character of degree \(16\)), but the centralizer of every element of \(O_{2'}(G) = 3^2\), the largest normal subgroup of \(G\) of odd order, has even order.

public theorem_wanted defectZeroBlockIffPRegularCentralizer_refuted :
    ¬ defectZeroBlockIffPRegularCentralizer

Sources

• E. I. Khukhro and V. D. Mazurov (eds.), Unsolved Problems in Group Theory: The Kourovka Notebook, 21st issue, arXiv:1401.0300v49 (2026), Archive of Solved Problems, Problem 12.26 (Shi Shengming; Jiping Zhang); resolution: V. I. Zenkov, Trudy Inst. Mat. i Mekh. UrO RAN 3 (1995), 36-40 (Russian), Kourovka Archive, Problem 12.26: No; G = 3^2.GL_2(3), p = 2.

Uses 1

Statement usesKourovka Problem 12.26

DefinitionCharacters of \(p\)-defect zero#✓fully proved

For a natural number \(p\) and a group \(G\), the set of characters \(\chi \colon G \to \mathbb{C}\) of irreducible finite-dimensional complex representations of \(G\) whose degree is divisible by \(p^a\), where \(a\) is the exponent of \(p\) in the prime factorization of the order \(|G|\) (and \(a = 0\) when \(G\) is infinite or \(p\) is not prime).

For a prime \(p\) and a finite group \(G\), each \(p\)-block of defect zero contains exactly one irreducible character, and every such character forms a block of defect zero (Brauer), so these characters count the \(p\)-blocks of defect zero.

def defectZeroCharacters (p : ℕ) (G : Type) [Group G] : Set (G → ℂ) :=
  {χ | ∃ (V : Type) (_ : AddCommGroup V) (_ : Module ℂ V) (_ : FiniteDimensional ℂ V)
    (ρ : Representation ℂ G V), ρ.IsIrreducible ∧ ρ.character = χ ∧
      p ^ (Nat.card G).factorization p ∣ Module.finrank ℂ V}

Used by 2

Used byKourovka Problem 12.80(a): blocks of defect zero and commutator equations · Kourovka Problem 12.80(b): the case of simple groups

DefinitionNumber of solutions of a commutator equation#✓fully proved

For an element \(g\) of a group \(G\), the number of pairs \((x, y) \in G \times G\) with \([x, y] = x y x^{-1} y^{-1} = g\), taken to be \(0\) when there are infinitely many such pairs.

noncomputable def commutatorSolutionCount {G : Type*} [Group G] (g : G) : ℕ :=
  Nat.card {xy : G × G // ⁅xy.1, xy.2⁆ = g}

Used by 1

Used byConjugacy classes with commutator count not divisible by \(p\)

DefinitionConjugacy classes with commutator count not divisible by \(p\)#✓fully proved

For a natural number \(p\) and a group \(G\), the set of conjugacy classes of \(G\) containing an element \(g\) such that the number of pairs \((x, y) \in G \times G\) with \([x, y] = x y x^{-1} y^{-1} = g\) (taken to be \(0\) when there are infinitely many) is not divisible by \(p\).

def nondivisibleCommutatorClasses (p : ℕ) (G : Type*) [Group G] : Set (ConjClasses G) :=
  {c | ∃ g : G, ConjClasses.mk g = c ∧ ¬ p ∣ commutatorSolutionCount g}

Uses 1 · Used by 2

Statement usesNumber of solutions of a commutator equation

Used byKourovka Problem 12.80(a): blocks of defect zero and commutator equations · Kourovka Problem 12.80(b): the case of simple groups

DefinitionKourovka Problem 12.80(a): blocks of defect zero and commutator equations#✓fully proved

For every prime \(p\) and every finite group \(G\) whose order is divisible by \(p\), the number of irreducible complex characters of \(G\) of \(p\)-defect zero equals the number of conjugacy classes of \(G\) containing an element \(g\) for which the number of pairs \((x, y) \in G \times G\) with \([x, y] = x y x^{-1} y^{-1} = g\) is not divisible by \(p\).

Each \(p\)-block of defect zero contains exactly one irreducible character, and every irreducible character of \(p\)-defect zero forms such a block (Brauer), so this is K. W. Roggenkamp's question whether the number of \(p\)-blocks of defect zero equals that number of classes.

def defectZeroBlocksEqNondivisibleClasses : Prop :=
  ∀ p : ℕ, p.Prime → ∀ (G : Type) [Group G] [Finite G], p ∣ Nat.card G →
    Nat.card (defectZeroCharacters p G) = Nat.card (nondivisibleCommutatorClasses p G)

Uses 2 · Used by 1

Statement usesCharacters of \(p\)-defect zero · Conjugacy classes with commutator count not divisible by \(p\)

Used byKourovka Problem 12.80(a) has a negative answer

DefinitionKourovka Problem 12.80(b): the case of simple groups#✓fully proved

For every prime \(p\) and every finite simple group \(G\) whose order is divisible by \(p\), the number of irreducible complex characters of \(G\) of \(p\)-defect zero equals the number of conjugacy classes of \(G\) containing an element \(g\) for which the number of pairs \((x, y) \in G \times G\) with \([x, y] = x y x^{-1} y^{-1} = g\) is not divisible by \(p\).

def simpleDefectZeroBlocksEqNondivisibleClasses : Prop :=
  ∀ p : ℕ, p.Prime → ∀ (G : Type) [Group G] [Finite G], IsSimpleGroup G → p ∣ Nat.card G →
    Nat.card (defectZeroCharacters p G) = Nat.card (nondivisibleCommutatorClasses p G)

Uses 2 · Used by 1

Statement usesCharacters of \(p\)-defect zero · Conjugacy classes with commutator count not divisible by \(p\)

Used byKourovka Problem 12.80(b) has a negative answer

TheoremKourovka Problem 12.80(a) has a negative answer#●ready to prove

It is not true that for every prime \(p\) and every finite group \(G\) whose order is divisible by \(p\), the number of irreducible complex characters of \(G\) of \(p\)-defect zero equals the number of conjugacy classes of \(G\) containing an element \(g\) for which the number of pairs \((x, y) \in G \times G\) with \([x, y] = x y x^{-1} y^{-1} = g\) is not divisible by \(p\).

L. Barker's counterexample: for \(p = 2\) and \(G = \mathbb{Z}_3 \times S_3\) there are three irreducible characters of degree \(2\), all of \(2\)-defect zero (so three \(2\)-blocks of defect zero), but only one class, that of \((1, (123))\), with an odd number of solutions of \([x, y] = g\).

public theorem_wanted defectZeroBlocksEqNondivisibleClasses_refuted :
    ¬ defectZeroBlocksEqNondivisibleClasses

Sources

• E. I. Khukhro and V. D. Mazurov (eds.), Unsolved Problems in Group Theory: The Kourovka Notebook, 21st issue, arXiv:1401.0300v49 (2026), Archive of Solved Problems, Problem 12.80 (K. W. Roggenkamp; S. P. Strunkov); resolution: L. Barker, letter of 27 May 1996 (part a); B. Sambale, letter of 5 May 2021 (part b); as recorded in the Kourovka Archive, Problem 12.80, (a) p = 2, G = ℤ_3 × S_3; (b) p = 2, G = A_5: one 2-block of defect zero, three classes ((123), (12345), (13524)) with an odd number of solutions of [x, y] = g, https://arxiv.org/abs/1401.0300v49.

Uses 1

Statement usesKourovka Problem 12.80(a): blocks of defect zero and commutator equations

TheoremKourovka Problem 12.80(b) has a negative answer#●ready to prove

It is not true that for every prime \(p\) and every finite simple group \(G\) whose order is divisible by \(p\), the number of irreducible complex characters of \(G\) of \(p\)-defect zero equals the number of conjugacy classes of \(G\) containing an element \(g\) for which the number of pairs \((x, y) \in G \times G\) with \([x, y] = x y x^{-1} y^{-1} = g\) is not divisible by \(p\).

B. Sambale's counterexample: in \(A_5\) with \(p = 2\) there is one irreducible character of \(2\)-defect zero (the character of degree \(4\), so one \(2\)-block of defect zero) but three classes, those of \((123)\), \((12345)\) and \((13524)\), with an odd number of solutions of \([x, y] = g\).

public theorem_wanted simpleDefectZeroBlocksEqNondivisibleClasses_refuted :
    ¬ simpleDefectZeroBlocksEqNondivisibleClasses

Sources

• E. I. Khukhro and V. D. Mazurov (eds.), Unsolved Problems in Group Theory: The Kourovka Notebook, 21st issue, arXiv:1401.0300v49 (2026), Archive of Solved Problems, Problem 12.80 (K. W. Roggenkamp; S. P. Strunkov); resolution: L. Barker, letter of 27 May 1996 (part a); B. Sambale, letter of 5 May 2021 (part b); as recorded in the Kourovka Archive, Problem 12.80, (a) p = 2, G = ℤ_3 × S_3; (b) p = 2, G = A_5: one 2-block of defect zero, three classes ((123), (12345), (13524)) with an odd number of solutions of [x, y] = g, https://arxiv.org/abs/1401.0300v49.

Uses 1

Statement usesKourovka Problem 12.80(b): the case of simple groups

8 fully proved3 ready to prove

The dependency explorer needs JavaScript and its graph data.

Download the complete graph data.